求一个将矩形批量转为三维面的程序！

用面域region命令即可。

region出来的不是三维面。

矩形不是一个严格的CAD图元定义。
CAD中的矩形命令做出的图元是一个有四个顶点且闭合的轻量化多段线(LWPOLYLINE)，下面的程序可以将这样的多段线转换成三维面(3DFACE)。命令tt
(defun c:tt( / ss  ename n i ptlst layer)
    (setq ss (ssget '((0 . "LWPOLYLINE") (90 . 4) (70 . 1))))
        (if ss
                (progn
                    (setq i  0)
                        (repeat (sslength ss)
                                (setq ename (ssname ss i)
                      layer (cdr (assoc 8 (entget ename)))                               
                                      i     (1+ i)
                                      ptlst (GET:LwPtUCSCor ename 0))
                                (entdel ename)
                                (DR:3dface layer ptlst)))))
;;子程序做3dface
(defun DR:3dface (layer ptlst)
        (entmake
                (list
                        '(0 . "3DFACE")
                        '(100 . "AcDbEntity")
                        (cons 8 layer)
                        '(100 . "AcDbFace")
                        (cons 10 (car ptlst))
                        (cons 11 (cadr ptlst))
                        (cons 12 (caddr ptlst))
                        (cons 13 (last ptlst))
                        '(70 . 0))))
;;子程序取lwpolyline的坐标
(defun GET:LwPtUCSCor (entname csflag / lwplellst lwplptlst z)
    (setq lwplellst  (entget entname)
                  z          (cdr (assoc 38 lwplellst))
              lwplptlst  (mapcar '(lambda(x) (cdr (reverse (cons z (reverse x))))) (vl-remove-if-not '(lambda(x) (= 10 (car x))) lwplellst)))
        (mapcar '(lambda(x)(trans x entname csflag)) lwplptlst))

对于首尾顶点重合，但闭合标志为不闭合的表观闭合lwpolyline及3dpoly生成的polyline没有考虑，如果有需要，可以增加相应的子函数并扩展代码。

用了一下，很好用，再次谢谢这位兄弟！